My Tension Gauge

Update: This is now on thingiverse as thing 163577.

All my quarters seem to go in vending machines, so I needed something different than ianjohnson's Belt Tension Gauge to provide weight for a belt tension gauge. I invented this variation using washers:

tension.scad

// Remix http://www.thingiverse.com/thing:38952 to extract just the hanger
// bit with the millimeter bumps on it. Flip it around to have a hanger
// on both sides.

module hanger_part() {
   intersection() {
      translate([0.89,-(5.04 + 0.74),0])
         import("Tension_Gauge.stl");
      translate([-50,0,0])
         cube([100,100,100]);
   }
}

// PART 1: The thing that hangs from the top belt.
//
module hanger() {
   union() {
      hanger_part();
      translate([0,1+2*6,0]) mirror([0,1,0]) hanger_part();
   }
}

// Now I want to hang washers off it instead of quarters. Looks like
// 6 quarters weigh 36 grams, so 1 quarter is 6 grams, so the 17
// quarters the original takes weighs 102 grams. An equivalent weight
// if 1/4 inch washers (which I happen to have a box of) is about
// 60 washers. Ten of the washers are 14.72 mm high when stacked up.
// The outer diameter is 15.82mm and the inner diameter is about 7mm.

innerdia = 7;

outerdia = 15.82;

thickness = 1.472;

washer_y = 2 + (thickness * 30);

washer_xz = 4;

post_sep = (outerdia/2)+(washer_xz/2)+1;

hanger_width = 10;

hanger_lip = 5;

module washer_post(extralen) {
   translate([-washer_xz/2, -washer_y/2, -washer_xz/2])
      cube([washer_xz, washer_y + extralen, washer_xz]);
}

// PART 2: The thing that hangs from the hanger and holds lots of 1/4 inch
// washers to provide weight.
//
module washers() {
   union() {
      washer_post(washer_xz+thickness);
      translate([-(hanger_width+2+2+0.5)/2, (washer_y/2) + washer_xz+thickness,
                 -(washer_xz/2)])
         difference() {
            cube([hanger_width+2+2+0.5,hanger_lip+2+2+0.5,washer_xz]);
            translate([2,2,-1])
               cube([hanger_width+0.5,hanger_lip+0.5,washer_xz+2]);
         }
      translate([post_sep,0,0])
         washer_post(washer_xz);
      translate([-post_sep,0,0])
         washer_post(washer_xz);
      translate([-(outerdia + 2*post_sep)/2, -(washer_y)/2, -washer_xz/2])
         cube([outerdia + 2*post_sep,washer_xz,washer_xz]);
   }
}

hanger.scad

include <tension.scad>

hanger();

washers.scad

include <tension.scad>

washers();

You can download a tarball of the openscad files as well as the STL files at tension.tar.bz2

Print out the two parts, stick them together, and add washers:

Not only are washers easier to obtain (or at least to keep around) in large quantities, but they seem a lot less likely to fall out when there is a post running through the holes :-).

Go back to my main Solidoodle page.